Controls the rendering of advanced anti-aliased text. The visual quality of text is very subjective, and while Flash Player tries to use the best settings for various conditions, designers may choose a different look or feel for their text. Also, using displayMode allows a designer to override Flash Player's subpixel choice and create visual consistency independent of the user's hardware.

The following values for displayMode allow the designer to set the global subpixel rendering mode for advanced anti-aliasing:

• "default" allows Flash Player to choose LCD or CRT mode.
• "lcd" forces Flash Player to use LCD sub-pixel antialiasing. Depending on the font and the hardware, this setting can result in much higher-resolution text or "coloring" of text.
• "crt" forces Flash Player to display grayscale antialiasing. While this setting avoids the "coloring" of text, some users may think it appears more "fuzzy".

Note: While this property is available for ActionScript 2.0, you can use it only when publishing to Flash Player 9 or later.

Sets the adaptively sampled distance fields (ADFs) quality level for advanced anti-aliasing. The only acceptable values are 3, 4, and 7. The default is 4.

Advanced anti-aliasing uses ADFs to represent the outlines that determine a glyph. The higher the quality, the more cache space is required for ADF structures. A value of 3 takes the least amount of memory and provides the lowest quality. Larger fonts require more cache space; at a font size of 64 pixels, the quality level increases from 3 to 4 or from 4 to 7 unless the level is already set to 7.

import flash.text.TextRenderer;
TextRenderer.maxLevel = 3;

var txtFormat:TextFormat = new TextFormat();
txtFormat.font = "CustomFont";
txtFormat.size = 64;

var label:TextField = this.createTextField("label", this.getNextHighestDepth(), 10, 10, 500, 100);
label.setNewTextFormat(txtFormat);
label.text = "Hello World";
label.embedFonts = true;
trace("TextRenderer.maxLevel: " + TextRenderer.maxLevel);

Sets a custom continuous stroke modulation (CSM) lookup table for a font. Flash Player attempts to detect the best CSM for your font. If you are not satisfied with the CSM that the Flash Player provides, you can customize your own CSM by using the setAdvancedAntialiasingTable() method.

1. Open your Library.
2. Click the Library options menu in the upper-right corner of the Library.
3. Select New Font from the pop-up menu.
4. Name the font myArial.
5. Select Arial from the font pop-up menu.
6. Click OK.
7. Right-click the newly created font, and select Linkage.
8. Select the Export for ActionScript check box.
9. Click OK to accept the default identifier, myArial.

import flash.text.TextRenderer;

var antiAliasEntry_1 = {fontSize:24, insideCutoff:1.61, outsideCutoff:-3.43};
var antiAliasEntry_2 = {fontSize:48, insideCutoff:0.8, outsideCutoff:-0.8};
var arialTable:Array = new Array(antiAliasEntry_1, antiAliasEntry_2);

var lbl_1:TextField = createLabel(0, 0, 300, 100, 24);
var lbl_2:TextField = createLabel(0, 100, 300, 100, 48);

TextRenderer.setAdvancedAntialiasingTable("Arial", "none", "dark", arialTable);

function createLabel(x:Number, y:Number, width:Number, height:Number, fontSize:Number):TextField {
    var depth:Number = this.getNextHighestDepth();
    
    var tmpTxt = this.createTextField("txt_" + depth, depth, x, y, width, height);
    tmpTxt.antiAliasType = "advanced";
    tmpTxt.gridFitType = "pixel";
    tmpTxt.border = true;
    tmpTxt.text = "Hello World";
    tmpTxt.embedFonts = true;
    tmpTxt.setTextFormat(getTextFormat(fontSize));
    return tmpTxt;
}

function getTextFormat(fontSize:Number):TextFormat {
    var tf:TextFormat = new TextFormat();
    tf.align = "center";
    tf.size = fontSize;
    tf.font = "myArial";
    return tf;
}