The number of seconds of data currently in the buffer. You can use this property in conjunction with NetStream.bufferTime to estimate how close the buffer is to being full--for example, to display feedback to a user who is waiting for data to be loaded into the buffer.

See also

this.createTextField("buffer_txt", this.getNextHighestDepth(), 10, 10, 300, 22);
buffer_txt.html = true;

var connection_nc:NetConnection = new NetConnection();
connection_nc.connect(null);
var stream_ns:NetStream = new NetStream(connection_nc);
stream_ns.setBufferTime(3);
my_video.attachVideo(stream_ns);
stream_ns.play("video1.flv");

var buffer_interval:Number = setInterval(checkBufferTime, 100, stream_ns);
function checkBufferTime(my_ns:NetStream):Void {
    var bufferPct:Number = Math.min(Math.round(my_ns.bufferLength/my_ns.bufferTime*100), 100);
    var output_str:String = "<textformat tabStops='[100,200]'>";
    output_str += "Length: "+my_ns.bufferLength+"\t"+"Time: "+my_ns.bufferTime+"\t"+"Buffer:"+bufferPct+"%";
    output_str += "</textformat>";
    buffer_txt.htmlText = output_str;
}

If your SWF file includes a version 2 component, use the version 2 components' DepthManager class instead of the MovieClip.getNextHighestDepth() method, which is used in this example.

The number of seconds assigned to the buffer by NetStream.setBufferTime(). The default value is .1(one-tenth of a second). To determine the number of seconds currently in the buffer, use NetStream.bufferLength.

See also

this.createTextField("buffer_txt", this.getNextHighestDepth(), 10, 10, 300, 22);
buffer_txt.html = true;

var connection_nc:NetConnection = new NetConnection();
connection_nc.connect(null);
var stream_ns:NetStream = new NetStream(connection_nc);
stream_ns.setBufferTime(3);
my_video.attachVideo(stream_ns);
stream_ns.play("video1.flv");

var buffer_interval:Number = setInterval(checkBufferTime, 100, stream_ns);
function checkBufferTime(my_ns:NetStream):Void {
    var bufferPct:Number = Math.min(Math.round(my_ns.bufferLength/my_ns.bufferTime*100), 100);
    var output_str:String = "<textformat tabStops='[100,200]'>";
    output_str += "Length: "+my_ns.bufferLength+"\t"+"Time: "+my_ns.bufferTime+"\t"+"Buffer:"+bufferPct+"%";
    output_str += "</textformat>";
    buffer_txt.htmlText = output_str;
}

If your SWF file includes a version 2 component, use the version 2 components' DepthManager class instead of the MovieClip.getNextHighestDepth() method, which is used in this example.

The number of bytes of data that have been loaded into the player. You can use this method in conjunction with NetStream.bytesTotal to estimate how close the buffer is to being full--for example, to display feedback to a user who is waiting for data to be loaded into the buffer.

See also

var connection_nc:NetConnection = new NetConnection();
connection_nc.connect(null);
var stream_ns:NetStream = new NetStream(connection_nc);
my_video.attachVideo(stream_ns);
stream_ns.play("video1.flv");

this.createTextField("loaded_txt", this.getNextHighestDepth(), 10, 10, 160, 22);
this.createEmptyMovieClip("progressBar_mc", this.getNextHighestDepth());
progressBar_mc.createEmptyMovieClip("bar_mc", progressBar_mc.getNextHighestDepth());
with (progressBar_mc.bar_mc) {
    beginFill(0xFF0000);
    moveTo(0, 0);
    lineTo(100, 0);
    lineTo(100, 10);
    lineTo(0, 10);
    lineTo(0, 0);
    endFill();
    _xscale = 0;
}
progressBar_mc.createEmptyMovieClip("stroke_mc", progressBar_mc.getNextHighestDepth());
with (progressBar_mc.stroke_mc) {
    lineStyle(0, 0x000000);
    moveTo(0, 0);
    lineTo(100, 0);
    lineTo(100, 10);
    lineTo(0, 10);
    lineTo(0, 0);
}

var loaded_interval:Number = setInterval(checkBytesLoaded, 500, stream_ns);
function checkBytesLoaded(my_ns:NetStream) {
    var pctLoaded:Number = Math.round(my_ns.bytesLoaded/my_ns.bytesTotal*100);
    loaded_txt.text = Math.round(my_ns.bytesLoaded/1000)+" of "+Math.round(my_ns.bytesTotal/1000)+" KB loaded ("+pctLoaded+"%)";
    progressBar_mc.bar_mc._xscale = pctLoaded;
    if (pctLoaded>=100) {
    clearInterval(loaded_interval);
    }
}

If your SWF file includes a version 2 component, use the version 2 components' DepthManager class instead of the MovieClip.getNextHighestDepth() method, which is used in this example.

The total size in bytes of the file being loaded into the player.

See also

var connection_nc:NetConnection = new NetConnection();
connection_nc.connect(null);
var stream_ns:NetStream = new NetStream(connection_nc);
my_video.attachVideo(stream_ns);
stream_ns.play("video1.flv");

this.createTextField("loaded_txt", this.getNextHighestDepth(), 10, 10, 160, 22);
this.createEmptyMovieClip("progressBar_mc", this.getNextHighestDepth());
progressBar_mc.createEmptyMovieClip("bar_mc", progressBar_mc.getNextHighestDepth());
with (progressBar_mc.bar_mc) {
    beginFill(0xFF0000);
    moveTo(0, 0);
    lineTo(100, 0);
    lineTo(100, 10);
    lineTo(0, 10);
    lineTo(0, 0);
    endFill();
    _xscale = 0;
}
progressBar_mc.createEmptyMovieClip("stroke_mc", progressBar_mc.getNextHighestDepth());
with (progressBar_mc.stroke_mc) {
    lineStyle(0, 0x000000);
    moveTo(0, 0);
    lineTo(100, 0);
    lineTo(100, 10);
    lineTo(0, 10);
    lineTo(0, 0);
}

var loaded_interval:Number = setInterval(checkBytesLoaded, 500, stream_ns);
function checkBytesLoaded(my_ns:NetStream) {
    var pctLoaded:Number = Math.round(my_ns.bytesLoaded/my_ns.bytesTotal*100);
    loaded_txt.text = Math.round(my_ns.bytesLoaded/1000)+" of "+Math.round(my_ns.bytesTotal/1000)+" KB loaded ("+pctLoaded+"%)";
    progressBar_mc.bar_mc._xscale = pctLoaded;
    if (pctLoaded>=100) {
    clearInterval(loaded_interval);
    }
}

If your SWF file includes a version 2 component, use the version 2 components' DepthManager class instead of the MovieClip.getNextHighestDepth() method, which is used in this example.

Specifies whether Flash Player should attempt to download a policy file from the loaded FLV file's server before beginning to load the FLV file itself. This flag is applicable when you are using a NetStream for progressive video download (standalone FLV files), but not when you are using a NetStream to obtain an RTMP asset.

Set this flag to true when you are loading an FLV video file from outside the calling SWF file's own domain and you expect to access the content of that image using BitmapData.draw(). If you attempt this operation without having specified checkPolicyFile at loading time, you may encounter a security error because the needed policy file has not been downloaded yet.

When you call NetStream.play() with checkPolicyFile set to true, Flash Player does not begin downloading the object specified in your call to play() until it has either successfully downloaded a relevant policy file or discovered that no such policy file exists. Flash Player first considers policy files that have already been downloaded, then attempts to download any pending policy files specified in calls to System.security.loadPolicyFile(), then attempts to download a policy file from the default location that corresponds to the URL you passed to play(), which is /crossdomain.xml on the same server as that URL. In all cases, Flash Player requires that the given policy file exists on its server, that the file provides access to the object at the URL you passed to play() by virtue of the policy file's location, and that the file permits access by the domain of the calling SWF by virtue of one or more <allow-access-from> tags.

If you set checkPolicyFile to true, Flash Player waits until policy file completion to begin the main download that you specify in play(). Thus, as long as the policy file that you need exists, as soon as you have received any onMetaData or onStatus events from your NetStream, the policy file download is complete and you can safely begin performing operations that require the policy file.

If you set checkPolicyFile to true, and no relevant policy file is found, you do not receive any error indication until you attempt an operation that throws a SecurityError exception.

Try to avoid setting checkPolicyFile to true if you will not be needing pixel-level access to the video that you are loading. Checking for a policy file in this case is wasteful because it may delay the start of your download and may consume network bandwidth unnecessarily.

Be careful with checkPolicyFile if you are downloading an FLV file from a URL that may use server-side HTTP redirects. Flash Player always attempts to retrieve policy files that correspond to the initial URL that you specify in NetStream.play(). If the final FLV file comes from a different URL because of HTTP redirects, then the initially downloaded policy file(s) might not be applicable to the FLV file's final URL, which is the URL that matters in security decisions.

The number of frames per second being displayed. If you are exporting FLV files to be played back on a number of systems, you can check this value during testing to help you determine how much compression to apply when exporting the file.

var connection_nc:NetConnection = new NetConnection();
connection_nc.connect(null);
var stream_ns:NetStream = new NetStream(connection_nc);
my_video.attachVideo(stream_ns);
stream_ns.play("video1.flv");

this.createTextField("fps_txt", this.getNextHighestDepth(), 10, 10, 50, 22);
fps_txt.autoSize = true;
var fps_interval:Number = setInterval(displayFPS, 500, stream_ns);
function displayFPS(my_ns:NetStream) {
    fps_txt.text = "currentFps (frames per second): "+Math.floor(my_ns.currentFps);
}

If your SWF file includes a version 2 component, use the version 2 components' DepthManager class instead of the MovieClip.getNextHighestDepth() method, which is used in this example.

The number of seconds of data in the specified subscribing stream’s buffer in live (unbuffered) mode. This property indicates the current network transmission delay (lag time). This property is intended primarily for use with Flash Media Server.

Specifies the maximum number of seconds to buffer messages during pause mode. The default value is 60 seconds or twice the value of NetStream.bufferTime on each pause, whichever is higher.

As soon as the value of NetStream.bufferLength reaches this limit, buffering stops.

See also

The position of the playhead, in seconds.

See also

var connection_nc:NetConnection = new NetConnection();
connection_nc.connect(null);
var stream_ns:NetStream = new NetStream(connection_nc);
my_video.attachVideo(stream_ns);
stream_ns.play("video1.flv");
//
stream_ns.onStatus = function(infoObject:Object) {
    statusCode_txt.text = infoObject.code;
};

this.createTextField("time_txt", this.getNextHighestDepth(), 10, 10, 100, 22);
time_txt.text = "LOADING";

var time_interval:Number = setInterval(checkTime, 500, stream_ns);
function checkTime(my_ns:NetStream) {
    var ns_seconds:Number = my_ns.time;
    var minutes:Number = Math.floor(ns_seconds/60);
    var seconds = Math.floor(ns_seconds%60);
    if (seconds<10) {
    seconds = "0"+seconds;
    }
    time_txt.text = minutes+":"+seconds;
}

If your SWF file includes a version 2 component, use the version 2 components' DepthManager class instead of the MovieClip.getNextHighestDepth() method, which is used in this example.

Creates a stream that can be used for playing FLV files through the specified NetConnection object.

See also

var connection_nc:NetConnection = new NetConnection();
connection_nc.connect(null);
var stream_ns:NetStream = new NetStream(connection_nc);
my_video.attachVideo(stream_ns);
stream_ns.play("video1.flv");

Specifies an audio stream to be sent over the NetStream object. This method is available only to the publisher of the specified stream.

The attachAudio() method is intended for use with Flash Media Server. It is typically called by a user sending live audio (or live video with audio) from a client computer to the server.

For more information, see the Flash Media Server documentation.

See also

Starts capturing video from the specified source, or stops capturing if the theCamera is null. This method is available only to the publisher of the specified stream.

For more information, see the Flash Media Server documentation.

See also

Stops playing all data on the stream, sets the NetStream.time property to 0, and makes the stream available for another use. This command also deletes the local copy of an FLV file that was downloaded using HTTP. Although Flash Player will delete the local copy of the FLV file that it creates, a copy of the video may persist in the browser's cache directory. If complete prevention of caching or local storage of the FLV file is required, use Flash Media Server.

See also

var connection_nc:NetConnection = new NetConnection();
connection_nc.connect(null);
var stream_ns:NetStream = new NetStream(connection_nc);
my_video.attachVideo(stream_ns);
stream_ns.play("video1.flv");

close_btn.onRelease = function(){
    stream_ns.close();
};

Returns an object containing various Quality of Service (QOS) statistics related to a NetStream object and its underlying streaming buffer for audio, video, and data. This method provides a snapshot of the current quality of service. For a list of the properties in the returned object, see the Flash Media Server documentation.

Pauses or resumes playback of a stream.

The first time you call this method (without sending a parameter), it pauses play; the next time, it resumes play. You might want to attach this method to a button that the user presses to pause or resume playback.

See also

my_ns.pause(); // pauses play first time issued
my_ns.pause(); // resumes play
my_ns.pause(false); // no effect, play continues
my_ns.pause(); // pauses play

Begins playback of an external video (FLV) file. To view video data, you must call a Video.attachVideo() method; audio being streamed with the video, or an FLV file that contains only audio, is played automatically.

You cannot connect to commonly reserved ports when you are using a null NetConnection. For a complete list of blocked ports, see the system.Security.loadPolicyFile() entry.

If you want to control the audio associated with an FLV file, you can use MovieClip.attachAudio() to route the audio to a movie clip; you can then create a Sound object to control some aspects of the audio. For more information, see MovieClip.attachAudio().

If the FLV file can't be found, the NetStream.onStatus event handler is invoked. If you want to stop a stream that is currently playing, use NetStream.close().

You can play local FLV files that are stored in the same directory as the SWF file or in a subdirectory; you can't navigate to a higher-level directory. For example, if the SWF file is located in a directory named /training, and you want to play a video stored in the /training/videos directory, you would use the following syntax:

my_ns.play("videos/videoName.flv");

To play a video stored in the /training directory, you would use the following syntax:

my_ns.play("videoName.flv");

When using this method, consider the Flash Player security model.

• NetStream.play() is not allowed if the calling SWF file is in the local-with-file-system sandbox and the resource is in a non-local sandbox.
• Network sandbox access from the local-trusted or local-with-networking sandbox requires permission from the website via a policy file.

For more information related to security, see the following:

• "Understanding Security" in Learning ActionScript 2.0 in Flash
• The Flash Player Developer Center Topic: Security

See also

// Play a file that is on the user's computer.
my_ns.play("file://joe_user/flash/videos/lectureJune26.flv");

// Play a file on a server.
my_ns.play("http://someServer.someDomain.com/flash/video/orientation.flv");

Plays streaming audio, video, and text messages being published to Flash Media Server, or plays a recorded stream stored on the server.

This method is available only to clients subscribed to the specified stream, not to the publisher of the stream.

Use the play2() method to switch to streams with the same content encoded at different bit rates or to swap streams in a playlist. This method lets an application adapt to changing network conditions or clients with different capabilities.

Supported file formats are FLV, MP3, ID3, and MPEG-4 based files such as F4V or MP4.

See also

Sends streaming audio, video, and text messages from clients to Flash Media Server, optionally recording the stream to a file during transmission. This method is available only to the publisher of the specified stream.

When you publish a stream, you can record or append it to a file in FLV, MP4, or F4V format. To record in MP4 or F4V format, prefix the stream name with "mp4:" and specify the file extension. The recorded filename is the name you pass in the name parameter. For example, ns.publish("mp4:streamName.f4v", "record") creates the file "streamName.f4v". The code ns.publish("mp4:streamName2.mp4", "record") creates the file "streamName2.mp4". You do not need to specify a file extension or a prefix when recording in FLV format.

The NetStream.publish() method does not play streams. To play streams, use the NetStream.play() method.

To report status, this method invokes NetStream.onStatus().

For more information about NetStream.publish(), see the Flash Media Server documentation.

See also

Specifies whether incoming audio plays on the specified stream. This method is available only to clients subscribed to the specified stream, not to the stream’s publisher.

You can call this method before or after you call the NetStream.play() method and begin receiving the stream.

If the specified stream contains only audio data, passing false to this method stops NetStream.time from incrementing.

For more information, see the Flash Media Server documentation.

See also

Specifies whether incoming video plays on the specified stream or specifies the frame rate of the video. If called with true or false, specifies whether to play incoming video on the stream.

Note: You can also call receiveVideo(FPS:Number) with a numeric parameter specifying the frame rate per second (FPS) to play the incoming video. The default FPS rate is the frame rate of the file or live stream being played. If you call this method with a frame rate parameter after calling NetStream.receiveVideo(false), an implicit call to NetStream.receiveVideo(true) is issued. For details on the receiveVideo(FPS:Number) version of this method, see the Flash Media Server documentation.

This method is available only to clients subscribed to the specified stream, not to the stream’s publisher.

See also

Seeks the keyframe closest to the specified number of seconds from the beginning of the stream. The stream resumes playing when it reaches the specified location in the stream.

See also

// Return to the beginning of the stream
my_ns.seek(0);

// Move to a location 30 seconds from the beginning of the stream
my_ns.seek(30);

// Move backwards three minutes from current location
my_ns.seek(my_ns.time - 180);

Broadcasts a message on the specified stream to all subscribing clients. This method is available only to the publisher of the specified stream. To process and respond to the message, create a handler in the format my_ns.handlerName.

Flash Player does not serialize methods or their data, object prototype variables, or non-enumerable variables. For movie clips, Flash Player serializes the path but none of the data.

You can also use the send() method to add keyframes of metadata to live streams or to clear metadata from a stream.

For more information, see the Flash Media Server documentation.

Specifies how long to buffer messages before starting to display the stream. For example, if you want to make sure that the first 15 seconds of the stream play without interruption, set bufferTime to 15; Flash begins playing the stream only after 15 seconds of data are buffered.

See also

public onCuePoint = function(infoObject:Object) {}

Invoked when an embedded cue point is reached while playing an FLV file. You can use this handler to trigger actions in your code when the video reaches a specific cue point. This lets you synchronize other actions in your application with video playback events.

There are two types of cue points that can be embedded in an FLV file.

• A "navigation" cue point specifies a keyframe within the FLV file and the cue point's time property corresponds to that exact keyframe. Navigation cue points are often used as bookmarks or entry points to let users navigate through the video file.
• An "event" cue point is specified by time, whether or not that time corresponds to a specific keyframe. An event cue point usually represents a time in the video when something happens that could be used to trigger other application events.

The onCuePoint() event handler receives an object with these properties:

You can define cue points in an FLV file when you first encode the file, or when you import a video clip in the Flash Authoring tool by using the Video Import wizard.

The onMetaData() event handler also retrieves information about the cue points in a video file. However the onMetaData() event handler gets information about all of the cue points before the video begins playing. The onCuePoint() event handler receives information about a single cue point at the time specified for that cue point during playback.

Generally if you want your code to respond to a specific cue point at the time it occurs you should use the onCuePoint() event handler to trigger some action in your code.

You can use the list of cue points provided to the onMetaData() event handler to let your user start playing the video at predefined points along the video stream. Pass the value of the cue point's time property to the NetStream.seek() method to play the video from that cue point.

var nc:NetConnection = new NetConnection();
nc.connect(null);
var ns:NetStream = new NetStream(nc);

ns.onCuePoint = function(infoObject:Object) 
{
    trace("onCuePoint:");
    for (var propName:String in infoObject) {
        if (propName != "parameters")
        {
            trace(propName + " = " + infoObject[propName]);
        }
        else
        {
            trace("parameters =");
            if (infoObject.parameters != undefined) {
                for (var paramName:String in infoObject.parameters)
                {
                    trace("   " + paramName + ": " + infoObject.parameters[paramName]);
                }
            }
            else
            {
                trace("undefined");
            }
        }        
    }
    trace("---------");    
}

ns.play("http://www.helpexamples.com/flash/video/cuepoints.flv");

This causes the following information to be displayed:

      onCuePoint:
      parameters =
         lights: beginning
      type = navigation
      time = 0.418
      name = point1
      ---------
      onCuePoint:
      parameters =
         lights: middle
      type = navigation
      time = 7.748
      name = point2
      ---------
      onCuePoint:
      parameters =
         lights: end
      type = navigation
      time = 16.02
      name = point3
      ---------

The parameter name "lights" is an arbitrary name used by the author of the example video. You can give cue point parameters any name you want.

See also

public onMetaData = function(infoObject:Object) {}

Invoked when the Flash Player receives descriptive information embedded in the FLV file being played.

The Flash Video Exporter utility (version 1.1 or greater) embeds a video's duration, creation date, data rates, and other information into the video file itself. Different video encoders embed different sets of metadata.

This handler is triggered after a call to the NetStream.play() method, but before the video playhead has advanced.

In many cases the duration value embedded in FLV metadata approximates the actual duration but is not exact. In other words it will not always match the value of the NetStream.time property when the playhead is at the end of the video stream.

var nc:NetConnection = new NetConnection();
nc.connect(null);
var ns:NetStream = new NetStream(nc);

ns.onMetaData = function(infoObject:Object) {
    for (var propName:String in infoObject) {
        trace(propName + " = " + infoObject[propName]);
    }
};

ns.play("http://www.helpexamples.com/flash/video/water.flv");

This causes the following information to be displayed:

canSeekToEnd = true
      videocodecid = 4
      framerate = 15
      videodatarate = 400
      height = 215
      width = 320
      duration = 7.347

The list of properties will vary depending on the software that was used to encode the FLV file.

See also

public onPlayStatus = function(infoObject:Object) {}

Invoked when a NetStream object has completely played a stream. To respond to this event, create a function to process the information object sent by the server.

For more information, see the Flash Media Server documentation.

See also

public onStatus = function(infoObject:Object) {}

Invoked every time a status change or error is posted for the NetStream object. If you want to respond to this event handler, you must create a function to process the information object.

The information object has a code property containing a string that describes the result of the onStatus handler, and a level property containing a string that is either status or error.

In addition to this onStatus handler, Flash also provides a "super" function called System.onStatus. If onStatus is invoked for a particular object and there is no function assigned to respond to it, Flash processes a function assigned to System.onStatus if it exists.

The following events notify you when certain NetStream activities occur.

If you consistently see errors regarding the buffer, you should try changing the buffer using the NetStream.setBufferTime() method.

For information on additional status codes, see the Flash Media Server documentation.

var connection_nc:NetConnection = new NetConnection();
connection_nc.connect(null);
var stream_ns:NetStream = new NetStream(connection_nc);
my_video.attachVideo(stream_ns);
stream_ns.play("video1.flv");
stream_ns.onStatus = function(infoObject:Object) {
        trace("NetStream.onStatus called: ("+getTimer()+" ms)");
        for (var prop in infoObject) {
            trace("\t"+prop+":\t"+infoObject[prop]);
        }
        trace("");
};

See also

public onTextData = function(textData:Object) {}

Invoked when a NetStream object receives text data embedded in a media file that is playing. To respond to this event, create a function to process the text data object sent by the server.

The text data is in UTF-8 format and can contain information about formatting based on the 3GPP timed text specification. For more information, see the 3GPP website.

For more information, see the Flash Media Server documentation.

See also

public onXMPData = function(data:Object) {}

Invoked when a NetStream object receives receives information specific to Adobe Extensible Metadata Platform (XMP) metadata embedded in the media being played. To respond to this event, create a function to process the data object sent by the server.

Adobe® Creative Suite® supports the creation and embedding of XMP metadata in files. Through the onXMP() callback method, Flash Media Server can deliver the XMP data embedded in FLV and F4V files.

Flash Media Server delivers but does not parse the XMP data embedded in a media file.

To parse the XMP data in the file, use XML parsing technology, for example, the XML class in ActionScript.

See also